การสร้างระบบแจ้งเตือนอุณหภูมิและความชื้นโดยใช้บอร์ด NodeMCU ESP8266 และเซนเซอร์ DHT22 พร้อมส่งการแจ้งเตือนไปยัง Telegram Bot เมื่อค่าที่อ่านได้เกินขีดจำกัดที่กำหนด ระบบนี้เหมาะสำหรับการตรวจสอบสภาพแวดล้อม เช่น ห้องเซิร์ฟเวอร์ โรงเรือนเพาะปลูก หรือพื้นที่ที่ต้องการควบคุมอุณหภูมิและความชื้น
เนื่องจากหลังจากวันที่ 31 มีนาคม 2568 ระบบ LINE Notify จะถูกปิดการให้บริการอย่างถาวร ทำให้มีผลกระทบต่อระบบที่ใช้บริการนี้อยู่ การเปลี่ยนมาใช้ Telegram เป็นทางเลือกที่สามารถรองรับการแจ้งเตือนได้ต่อไป
บทความเดิมที่แนะนำเรื่องการเชื่อมต่อและอุปกรณ์ที่ต้องใช้ ในที่นี้จะอธิบายต่อในส่วนของการใช้งาน Telegram Bot การสร้างและการนำคีย์มาใช้งาน https://moremeng.in.th/2023/02/nodemcu-esp8266-dht22-dht-11-temperature-humidity-detect-and-notify-line.html
แจ้งเตือนผ่าน Telegram
การแจ้งเตือนจะใช้ได้ 2 แบบ แบบส่วนตัว และ แบบแจ้งในกลุ่ม
- การแจ้งแบบส่วนตัว จะใช้
id ของผู้ใช้งานtelegram ซึ่งต้องเป็นเพื่อนกับ Bot - การแจ้งแบบกลุ่ม จะใช้
id ของกลุ่มไม่ต้องเป็นเพื่อนกับ bot
การสร้าง Telegram Bot และการดึงเข้ากลุ่ม
1. สร้าง Telegram Bot
- เปิด Telegram และค้นหา
@BotFather - พิมพ์คำสั่ง
/newbot - กรอก ชื่อบอท (เช่น
🔥เทอโม้) - กรอก username ของบอท (ต้องลงท้ายด้วย
botเช่นTermoBot) - BotFather จะส่ง API Token มาให้ นำไปใช้ในการพัฒนา (ในกรอบสีแดง)
2. ดึง Bot เข้ากลุ่ม (เพื่อให้ Bot แจ้งเตือนในกลุ่มได้ หากไม่ต้องการใช้ให้ข้ามไป ข้อ 5)
- ไปที่กลุ่มที่ต้องการเพิ่มบอท
- กดที่ชื่อกลุ่ม > Manage Group > Administrators
- กด Add Administrator และเลือกบอทที่สร้างไว้
- ตั้งค่าบอทให้มีสิทธิ์ที่จำเป็น (เช่น
Post Messages,Delete Messagesฯลฯ)
3. หา Chat ID ของกลุ่ม
- ใช้บอทที่สร้างขึ้นในข้อ 1 แล้วพิมพ์
/startเพื่อดูข้อมูลกลุ่ม - หรือใช้ API ของ Telegram:
- ส่งข้อความไปที่กลุ่มที่มีบอทอยู่
- ใช้ API ดึงอัปเดต:
https://api.telegram.org/bot<TOKEN>/getUpdates - ดูค่า
"chat":{"id":-xxxxxxxxx}(เลขติดลบคือ Chat ID ของกลุ่ม)
"chat": {
"id": -470xxxx140,
"title": "ICT-ONLINE",
"type": "group",
"all_members_are_administrators": true
},4. ทดสอบส่งข้อความไปยังกลุ่ม
ใช้ API ของ Telegram:
https://api.telegram.org/bot<TOKEN>/sendMessage?chat_id=-XXXXXXXXX&text=Hello, Group!
(แทนที่ <TOKEN> และ -XXXXXXXXX ด้วยค่าที่ได้มา)
5. หา ID ของผู้ใช้งาน
- ค้นหา
@userinfobotในช่องค้นหา - กดเริ่มต้น (
Start) - บอทจะแสดงข้อมูลของคุณทันที
ลองนำ id ไปทดสอบส่งข้อความหาผู้ใช้งานได้
https://api.telegram.org/bot<TOKEN>/sendMessage?chat_id=-XXXXXXXXX&text=Hello!
แจ้งเตือนผ่าน Telegram
ชุดคำสั่งนี้ทำงานเหมือนเดิม ต่างกันตรงที่แจ้งเตือนผ่าน telegram แทน line notify โดยใช้งาน library UniversalTelegramBot.h และ ArduinoJson.h ในส่วนของวิธีการ compile ใส่ใน module นั้นก็สามารถอ่านได้จากบทความข้างต้นได้ โดยในคำสั่งนี้จะมีการแจ้งสถานะการ Online ของอุปกรณ์ไปยัง telegram ด้วย เพื่อให้ทราบว่าสามารถเชื่อมต่อ internet ได้แล้ว
#include <ESP8266WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>
#include <ArduinoJson.h>
#include "DHT.h"
// NodeMCU Name
#define NODE "NodeMCU_3"
// Replace with your network details
const char *ssid = "WIFI_NAME";
const char *password = "WIFI_PASSWORD";
// Telegram BOT Token (Get from Botfather)
const char *TELEGRAM_BOT_TOKEN = "TELEGRAM_BOT_TOKEN";
const char *CHAT_ID = "CHAT_ID"; // Chat ID
// Uncomment one of the lines below for whatever DHT sensor type you're using!
// #define DHTTYPE DHT11 // DHT 11
// #define DHTTYPE DHT21 // DHT 21 (AM2301)
#define DHTTYPE DHT22 // DHT 22 (AM2302), AM2321
#define DHTPIN D1 // Digital pin connected to the DHT sensor
// Feather HUZZAH ESP8266 note: use pins 3, 4, 5, 12, 13 or 14 --
// Pin 15 can work but DHT must be disconnected during program upload.
// Initialize DHT sensor.
DHT dht(DHTPIN, DHTTYPE);
// Temporary variables
static char celsiusTemp[7];
static char fahrenheitTemp[7];
static char humidityTemp[7];
X509List cert(TELEGRAM_CERTIFICATE_ROOT);
WiFiClientSecure secured_client;
UniversalTelegramBot bot(TELEGRAM_BOT_TOKEN, secured_client);
// only runs once on boot
void setup() {
delay(1000);
Serial.begin(9600);
WiFi.mode(WIFI_OFF); // Prevents reconnection issue (taking too long to connect)
delay(1000);
WiFi.mode(WIFI_STA); // This line hides the viewing of ESP as wifi hotspot
WiFi.begin(ssid, password); // Connect to your WiFi router
Serial.println("");
Serial.print("Connecting");
// Wait for connection
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
// If connection successful show IP address in serial monitor
Serial.println("");
Serial.print("Connected to ");
Serial.println(ssid);
Serial.print("IP address: ");
Serial.println(WiFi.localIP()); // IP address assigned to your ESP
secured_client.setTrustAnchors(&cert); // Add root certificate for api.telegram.org
Serial.print("Retrieving time: ");
configTime(0, 0, "pool.ntp.org"); // get UTC time via NTP
time_t now = time(nullptr);
while (now < 24 * 3600) {
Serial.print(".");
delay(100);
now = time(nullptr);
}
Serial.println(now);
bot.sendMessage(CHAT_ID, String(NODE) + " : Online 🟢", "");
dht.begin();
}
void loop() {
// runs over and over again
/**
* @brief Main loop function that continuously monitors and reports temperature and humidity.
*
* This function performs the following tasks:
* 1. Waits for a WiFi connection.
* 2. Reads temperature and humidity from the DHT sensor.
* 3. Checks if the sensor readings are valid.
* 4. Computes the heat index in both Celsius and Fahrenheit.
* 5. Prints the humidity, temperature, and heat index values to the Serial monitor.
* 6. Sends a Telegram message if the heat index exceeds 45°C.
* 7. Delays for 20 seconds before repeating the process.
*/
// wait for WiFi connection
if ((WiFi.status() == WL_CONNECTED)) {
// Reading temperature or humidity takes about 250 milliseconds!
// Sensor readings may also be up to 2 seconds 'old' (its a very slow sensor)
float h = dht.readHumidity();
// Read temperature as Celsius (the default)
float t = dht.readTemperature();
// Read temperature as Fahrenheit (isFahrenheit = true)
float f = dht.readTemperature(true);
// Check if any reads failed and exit early (to try again).
if (isnan(h) || isnan(t) || isnan(f)) {
Serial.println(F("Failed to read from DHT sensor!"));
return;
}
// Compute heat index in Fahrenheit (the default)
float hif = dht.computeHeatIndex(f, h);
// Compute heat index in Celsius (isFahreheit = false)
float hic = dht.computeHeatIndex(t, h, false);
Serial.print(F("Humidity: "));
Serial.print(h);
Serial.print(F("% Temperature: "));
Serial.print(t);
Serial.print(F("°C "));
Serial.print(f);
Serial.print(F("°F Heat index: "));
Serial.print(hic);
Serial.print(F("°C "));
Serial.print(hif);
Serial.println(F("°F"));
if (hic > 45.00) {
if (sendTelegramMessage("😐 ดูเหมือนห้องจะร้อนนะครับ\n" + String(NODE) + " : Heat index " + String(hic) + "°C " + "\n🌡 " + String(t) + "°C 💧" + String(h) + "%")) {
Serial.println("Send Message successful");
} else {
Serial.println("Error sending message");
}
}
}
delay(20000);
}
bool sendTelegramMessage(String message) {
bool result = bot.sendMessage(CHAT_ID, message, "");
if (!result) {
Serial.println("Failed to send message to Telegram");
}
return result;
}
สรุป
การใช้ Telegram แทน LINE Notify มีประโยชน์มากในแง่ของการไม่ต้องเสียค่าใช้จ่าย และเหมาะสำหรับการแจ้งเตือนจากอุปกรณ์ IoT เช่น NodeMCU ESP8266 โดยสามารถตั้งค่าให้ส่งข้อความเตือนในกรณีต่างๆ ได้ง่ายและรวดเร็ว โดยไม่จำเป็นต้องพึ่งพาบริการที่มีค่าใช้จ่ายเพิ่มเติม ซึ่ง Telegram ยังรองรับการส่งข้อมูลจำนวนมากและการทำงานอัตโนมัติผ่านบอทที่สามารถจัดการกับข้อมูลที่ส่งจากอุปกรณ์ IoT ได้อย่างมีประสิทธิภาพ ทำให้เหมาะสมกับการใช้งานในระบบที่ต้องการความคุ้มค่าและการแจ้งเตือนทันทีจากอุปกรณ์ต่างๆ ที่เชื่อมต่อผ่านอินเทอร์เน็ต.
